Added solution for "Day 11: Cosmic Expansion", part 1

solvers/UCosmicExpansion.pas

@@ -0,0 +1,127 @@
+{
+  Solutions to the Advent Of Code.
+  Copyright (C) 2023  Stefan Müller
+
+  This program is free software: you can redistribute it and/or modify it under
+  the terms of the GNU General Public License as published by the Free Software
+  Foundation, either version 3 of the License, or (at your option) any later
+  version.
+
+  This program is distributed in the hope that it will be useful, but WITHOUT
+  ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
+  FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
+
+  You should have received a copy of the GNU General Public License along with
+  this program.  If not, see <http://www.gnu.org/licenses/>.
+}
+
+unit UCosmicExpansion;
+
+{$mode ObjFPC}{$H+}
+
+interface
+
+uses
+  Classes, SysUtils, Generics.Collections, Math, USolver;
+
+const
+  CGalaxyChar = '#';
+  CEmptySpaceFactor = 2;
+  CNonEmptySpaceFactor = 1;
+
+type
+
+  { TCosmicExpansion }
+
+  TCosmicExpansion = class(TSolver)
+  private
+    FColumnExpansion, FRowExpansion: specialize TList<Integer>;
+    FGalaxies: specialize TList<TPoint>;
+    procedure InitColumnExpansion(const ASize: Integer);
+  public
+    constructor Create;
+    destructor Destroy; override;
+    procedure ProcessDataLine(const ALine: string); override;
+    procedure Finish; override;
+    function GetDataFileName: string; override;
+    function GetPuzzleName: string; override;
+  end;
+
+implementation
+
+{ TCosmicExpansion }
+
+procedure TCosmicExpansion.InitColumnExpansion(const ASize: Integer);
+var
+  i: Integer;
+begin
+  if FColumnExpansion.Count = 0 then
+  begin
+    FColumnExpansion.Capacity := ASize;
+    for i := 1 to ASize do
+      FColumnExpansion.Add(CEmptySpaceFactor);
+  end;
+end;
+
+constructor TCosmicExpansion.Create;
+begin
+  FColumnExpansion := specialize TList<Integer>.Create;
+  FRowExpansion := specialize TList<Integer>.Create;
+  FGalaxies := specialize TList<TPoint>.Create;
+end;
+
+destructor TCosmicExpansion.Destroy;
+begin
+  FColumnExpansion.Free;
+  FRowExpansion.Free;
+  FGalaxies.Free;
+  inherited Destroy;
+end;
+
+procedure TCosmicExpansion.ProcessDataLine(const ALine: string);
+var
+  empty: Boolean;
+  i : Integer;
+begin
+  InitColumnExpansion(Length(ALine));
+
+  empty := True;
+  for i := 1 to Length(ALine) do
+    if ALine[i] = CGalaxyChar then
+    begin
+      FGalaxies.Add(Point(i, FRowExpansion.Count));
+      empty := False;
+      FColumnExpansion[i - 1] := CNonEmptySpaceFactor;
+    end;
+
+  if empty then
+    FRowExpansion.Add(CEmptySpaceFactor)
+  else
+    FRowExpansion.Add(CNonEmptySpaceFactor);
+end;
+
+procedure TCosmicExpansion.Finish;
+var
+  i, j, k: Integer;
+begin
+  for i := 0 to FGalaxies.Count - 1 do
+    for j := i + 1 to FGalaxies.Count - 1 do begin
+      for k := Min(FGalaxies[i].X, FGalaxies[j].X) to Max(FGalaxies[i].X, FGalaxies[j].X) - 1 do
+        Inc(FPart1, FColumnExpansion[k]);
+      for k := Min(FGalaxies[i].Y, FGalaxies[j].Y) + 1 to Max(FGalaxies[i].Y, FGalaxies[j].Y) do
+        Inc(FPart1, FRowExpansion[k]);
+    end;
+end;
+
+function TCosmicExpansion.GetDataFileName: string;
+begin
+  Result := 'cosmic_expansion.txt';
+end;
+
+function TCosmicExpansion.GetPuzzleName: string;
+begin
+   Result := 'Day 11: Cosmic Expansion';
+end;
+
+end.
+