AdventOfCode2023/USolver.pas

{
  Solutions to the Advent Of Code.
  Copyright (C) 2023  Stefan Müller

  This program is free software: you can redistribute it and/or modify it under
  the terms of the GNU General Public License as published by the Free Software
  Foundation, either version 3 of the License, or (at your option) any later
  version.

  This program is distributed in the hope that it will be useful, but WITHOUT
  ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more details.

  You should have received a copy of the GNU General Public License along with
  this program.  If not, see <http://www.gnu.org/licenses/>.
}

unit USolver;

{$mode ObjFPC}{$H+}
{$interfaces corba}

interface

uses
  Classes, SysUtils;

type

  { ISolver }

  ISolver = interface
    procedure Init;
    procedure ProcessDataLine(const ALine: string);
    procedure Finish;
    procedure Free;
    function GetDataFileName: string;
    function GetPuzzleName: string;
    function GetResultPart1: Int64;
    function GetResultPart2: Int64;
    property DataFileName: string read GetDataFileName;
    property PuzzleName: string read GetPuzzleName;
    property ResultPart1: Int64 read GetResultPart1;
    property ResultPart2: Int64 read GetResultPart2;
  end;

  { TSolver }

  TSolver = class abstract(ISolver)
  protected
    FPart1, FPart2: Int64;
  public
    procedure Init; virtual;
    procedure ProcessDataLine(const ALine: string); virtual; abstract;
    procedure Finish; virtual; abstract;
    function GetDataFileName: string; virtual; abstract;
    function GetPuzzleName: string; virtual; abstract;
    function GetResultPart1: Int64; virtual;
    function GetResultPart2: Int64; virtual;
  end;

  { TSolverEngine }

  TSolverEngine = class
  private
    FRelativeDataPaths: TStringArray;
  public
    constructor Create(constref ARelativeDataPaths: TStringArray);
    procedure ProcessData(const ASolver: ISolver);
    procedure Run(const ASolver: ISolver);
    procedure RunAndFree(const ASolver: ISolver);
    function HasValidDataPath(const ASolver: ISolver): Boolean;
    function TryGetFirstValidDataPath(const ASolver: ISolver; out ODataFilePath: string): Boolean;
    function GetInvalidDataPathMessage(const ASolver: ISolver): string;
  end;

implementation

{ TSolver }

procedure TSolver.Init;
begin
  FPart1 := 0;
  FPart2 := 0;
end;

function TSolver.GetResultPart1: Int64;
begin
  Result := FPart1;
end;

function TSolver.GetResultPart2: Int64;
begin
  Result := FPart2;
end;

{ TSolverEngine }

constructor TSolverEngine.Create(constref ARelativeDataPaths: TStringArray);
begin
  if (ARelativeDataPaths = nil) or (Length(ARelativeDataPaths) = 0) then
    raise EArgumentOutOfRangeException.Create('Must specify at least one data path.');
  FRelativeDataPaths := ARelativeDataPaths;
end;

procedure TSolverEngine.ProcessData(const ASolver: ISolver);
var
  data: TextFile;
  dataFilePath, s: string;
begin
  ASolver.Init;

  TryGetFirstValidDataPath(ASolver, dataFilePath);
  AssignFile(data, dataFilePath);
  try
    reset(data);
    while (not EOF(data)) do
    begin
      readln(data, s);
      ASolver.ProcessDataLine(s);
    end;
  finally
    CloseFile(data)
  end;

  ASolver.Finish;
end;

procedure TSolverEngine.Run(const ASolver: ISolver);
begin
  WriteLn;
  WriteLn('--- ', ASolver.PuzzleName, ' ---');
  if HasValidDataPath(ASolver) then
  begin
    ProcessData(ASolver);
    WriteLn('Part 1: ', ASolver.ResultPart1);
    WriteLn('Part 2: ', ASolver.ResultPart2);
  end
  else
    WriteLn(GetInvalidDataPathMessage(ASolver));
end;

procedure TSolverEngine.RunAndFree(const ASolver: ISolver);
begin
  Run(ASolver);
  ASolver.Free;
end;

function TSolverEngine.HasValidDataPath(const ASolver: ISolver): Boolean;
var
  s: string;
begin
  Result := TryGetFirstValidDataPath(ASolver, s);
end;

function TSolverEngine.TryGetFirstValidDataPath(const ASolver: ISolver; out ODataFilePath: string): Boolean;
var
  path: string;
begin
  for path in FRelativeDataPaths do
  begin
    ODataFilePath := ConcatPaths([path, ASolver.DataFileName]);
    if FileExists(ODataFilePath) then
    begin
      Result := True;
      Exit;
    end;
  end;

  Result := False;
  ODataFilePath := '';
end;

function TSolverEngine.GetInvalidDataPathMessage(const ASolver: ISolver): string;
var
  i: Integer;
begin
  Result := 'Cannot find puzzle input file '''
    + ExpandFileName(ConcatPaths([FRelativeDataPaths[0], ASolver.DataFileName]));
  for i := 1 to Length(FRelativeDataPaths) - 1 do
    Result := Result + ''', or '''
      + ExpandFileName(ConcatPaths([FRelativeDataPaths[i], ASolver.DataFileName]));
  Result := Result + '''. Please download the file content from https://adventofcode.com/2023/';
end;

end.