AdventOfCode2023/USolver.pas

{
  Solutions to the Advent Of Code.
  Copyright (C) 2023  Stefan Müller

  This program is free software: you can redistribute it and/or modify it under
  the terms of the GNU General Public License as published by the Free Software
  Foundation, either version 3 of the License, or (at your option) any later
  version.

  This program is distributed in the hope that it will be useful, but WITHOUT
  ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more details.

  You should have received a copy of the GNU General Public License along with
  this program.  If not, see <http://www.gnu.org/licenses/>.
}

unit USolver;

{$mode ObjFPC}{$H+}
{$interfaces corba}

interface

uses
  Classes, SysUtils;

type

  { ISolver }

  ISolver = interface
    procedure Init;
    procedure ProcessDataLine(const ALine: string);
    procedure Finish;
    procedure Free;
    function GetDataFileName: string;
    function GetPuzzleName: string;
    function GetResultPart1: Int64;
    function GetResultPart2: Int64;
    property DataFileName: string read GetDataFileName;
    property PuzzleName: string read GetPuzzleName;
    property ResultPart1: Int64 read GetResultPart1;
    property ResultPart2: Int64 read GetResultPart2;
  end;

  { TSolver }

  TSolver = class abstract(ISolver)
  protected
    FPart1, FPart2: Int64;
  public
    procedure Init; virtual;
    procedure ProcessDataLine(const ALine: string); virtual; abstract;
    procedure Finish; virtual; abstract;
    function GetDataFileName: string; virtual; abstract;
    function GetPuzzleName: string; virtual; abstract;
    function GetResultPart1: Int64; virtual;
    function GetResultPart2: Int64; virtual;
  end;

  { TSolverEngine }

  TSolverEngine = class
  private
    FRelativeDataPath: string;
  public
    constructor Create(const ARelativeDataPath: string);
    procedure ProcessData(const ASolver: ISolver);
    procedure Run(const ASolver: ISolver);
    procedure RunAndFree(const ASolver: ISolver);
  end;

implementation

{ TSolver }

procedure TSolver.Init;
begin
  FPart1 := 0;
  FPart2 := 0;
end;

function TSolver.GetResultPart1: Int64;
begin
  Result := FPart1;
end;

function TSolver.GetResultPart2: Int64;
begin
  Result := FPart2;
end;

{ TSolverEngine }

constructor TSolverEngine.Create(const ARelativeDataPath: string);
begin
  FRelativeDataPath := ARelativeDataPath;
end;

procedure TSolverEngine.ProcessData(const ASolver: ISolver);
var
  data: TextFile;
  s: string;
begin
  ASolver.Init;

  AssignFile(data, ConcatPaths([FRelativeDataPath, ASolver.DataFileName]));
  try
    reset(data);
    while (not EOF(data)) do
    begin
      readln(data, s);
      ASolver.ProcessDataLine(s);
    end;
  finally
    CloseFile(data)
  end;

  ASolver.Finish;
end;

procedure TSolverEngine.Run(const ASolver: ISolver);
begin
  WriteLn;
  WriteLn('--- ', ASolver.PuzzleName, ' ---');
  ProcessData(ASolver);
  WriteLn('Part 1: ', ASolver.ResultPart1);
  WriteLn('Part 2: ', ASolver.ResultPart2);
end;

procedure TSolverEngine.RunAndFree(const ASolver: ISolver);
begin
  Run(ASolver);
  ASolver.Free;
end;

end.